The k3 online help indicates

scatter selection       matrix'

How can we use this function? The left (first) argument, matrix, specifies where we are selecting from, and the right argument specifies the coordinates of the items being selected

When selecting a single element, scatter selection and indexing are the same

  ((0 1 2);(3 4 5);(6 7 8))[1;2]
5

  ((0 1 2);(3 4 5);(6 7 8))'[1;2]
5

The difference however is when we want to select more than one element, indexing would give us a subarray

  ((0 1 2);(3 4 5);(6 7 8))[1 2;2 0]
(5 3
 8 6)

but scatter selection would give us just the selected arguments

  ((0 1 2);(3 4 5);(6 7 8))'[1 2;2 0]
5 6

or,

  ("abc";"def";"ghi")'[0 1 0;0 2 1]
"afb"

Scatter selection is not restricted to 2D matrices, it can be used for higher dimension arrays (tensors), and the valence of the scatter selection will depend on the dimensions of the array, e.g, for a 3D array we should provide 3 vectors of coordinates

  (((0 1 2);(3 4 5);(6 7 8));((10 11 12);(13 14 15);(16 17 18));((20 21 22);(23 24 25);(26 27 28)))'[0 1;0 2;0 0]
0 16

or,

  (4#,("abc";"def";"ghi"))'[0 1 0;0 2 1;0 0 0]
"agd"

If we specify fewer vectors of coordinates less than the dimensions of the array, then the array will be re-interpreted as the appropriate array of arrays (e.g., as a matrix of sub-vectors or a matrix of sub-matrices)

  (((0 1 2);(3 4 5);(6 7 8));((10 11 12);(13 14 15);(16 17 18));((20 21 22);(23 24 25);(26 27 28)))'[0 1;0 2]
(0 1 2
 16 17 18)

or,

  (4#,("abc";"def";"ghi"))'[0 1 0;0 2 1]
("abc"
 "ghi"
 "def")

an example with a matrix of sub-matrices

  (3#,(((0 1 2);(3 4 5);(6 7 8));((10 11 12);(13 14 15);(16 17 18));((20 21 22);(23 24 25);(26 27 28))))'[0 1;0 2]
((0 1 2
  3 4 5
  6 7 8)
 (20 21 22
  23 24 25
  26 27 28))

There is a limit however, that the minimum number of arguments is 2 lists, if we try to go down to a single list it will result in a projection

  (((0 1 2);(3 4 5);(6 7 8));((10 11 12);(13 14 15);(16 17 18));((20 21 22);(23 24 25);(26 27 28)))'[0 1]
((0 1 2
  3 4 5
  6 7 8)
 (10 11 12
  13 14 15
  16 17 18)
 (20 21 22
  23 24 25
  26 27 28))'[0 1]

Multiple options can be selected.