{
"Life" in FALSE

input is for example:

..-.
--..
....
...-
}

B

4g:
g;1+[1-$]
   [
    g;1+[1-$][^'*=@@]#%^%
   ]#%

g;$z:$*e:


[z;1-$z:1_=~]
 [g;s:

  [s;1-$s:1_=~]
    [e;1-e:

     0n:

     z;g;1-=~
         [ s;g;1-=~[e;g;+1+O[n;1+n:]?]?
           e;g;+O[n;1+n:]?
           s;0>[e;g;+1-O[n;1+n:]?]?
         ]?

     s;g;1-=~[e;1+O[n;1+n:]?]?
     s;0>[e;1-O[n;1+n:]?]?

     z;0=~
         [ s;g;1-=~[e;g;-1+O[n;1+n:]?]?
           e;g;-O[n;1+n:]?
           s;0>[e;g;-1-O[n;1+n:]?]?
         ]?

     e;O$[n;$2=\3=|$['*,]?~['.,]?]?
        ~[n;3=$['*,]?~['.,]?]?
    ]#10,

 ]#
g;$*1+[1-$][\'.+%]#%10,
